home *** CD-ROM | disk | FTP | other *** search
/ Amiga ISO Collection / AmigaUtilCD1.iso / Backup / FLD-BM14.LHA / BackMan / Install BackMan < prev    next >
Encoding:
Text File  |  1996-11-17  |  4.6 KB  |  233 lines
  1. ;**
  2. ;**  $VER: Install 1.2 (17.11.96)
  3. ;**  Copyright © 1995-1996 Flavio Stanchina
  4. ;**
  5.  
  6. ;**
  7. ;**  English strings
  8. ;**
  9.  
  10. (if (= @language "english") (
  11.   (set #bad-kick "This program requires kickstart V39 (3.0) or higher.")
  12.   (set #bad-mui "You must install MUI 3.3 or higher before installing BackMan!")
  13.   (set #inst-bin "Installing BackMan binaries")
  14.   (set #inst-key "Installing BackMan keyfile")
  15.   (set #inst-cat "Installing catalog files")
  16.   (set #inst-doc "Installing documentation")
  17.   (set #inst-hlp "Installing online help")
  18.   (set #inst-xpk "Installing XPK libraries:\n")
  19.   (set #choose-dest "Choose where BackMan's drawer will be created")
  20.   (set #choose-doclang "Choose the documentation's language")
  21.   (set #choose-catlang "Choose which catalogs you want to install")
  22.   (set #ask-doc "Do you want to install the documentation?")
  23.   (set #welcome "Welcome registered user! Thanks for your support!")
  24.   (set #language "English") ;Default doc language
  25.   (set #langnum 0)
  26. ))
  27.  
  28. ;**
  29. ;**  Italian strings
  30. ;**
  31.  
  32. (if (= @language "italiano") (
  33.   (set #bad-kick "Questo programma richiede il kickstart V39 (3.0) o superiore.")
  34.   (set #bad-mui "Devi installare MUI 3.3 o superiore prima di installare BackMan!")
  35.   (set #inst-bin "Installazione dei programmi")
  36.   (set #inst-key "Installazione della chiave")
  37.   (set #inst-cat "Installazione dei cataloghi")
  38.   (set #inst-doc "Installazione della documentazione")
  39.   (set #inst-hlp "Installazione dell'help in linea")
  40.   (set #inst-xpk "Installazione delle librerie XPK:\n")
  41.   (set #choose-dest "Scegli dove verrà creato il cassetto di BackMan")
  42.   (set #choose-doclang "Scegli la lingua della documentazione")
  43.   (set #choose-catlang "Scegli quali cataloghi vuoi installare")
  44.   (set #ask-doc "Vuoi installare la documentazione?")
  45.   (set #welcome "Benvenuto utente registrato! Grazie per il tuo supporto!")
  46.   (set #language "Italiano") ;Default doc language
  47.   (set #langnum 1)
  48. ))
  49.  
  50. ;**
  51. ;**  Startup checks
  52. ;**
  53.  
  54. (if (< (/ (getversion) 65536) 39) (
  55.   (abort #bad-kick)
  56. ))
  57.  
  58. (if (< (/ (getversion "LIBS:muimaster.library") 65536) 14) (
  59.   (abort #bad-mui)
  60. ))
  61.  
  62. ;**
  63. ;**  Installing BackMan!
  64. ;**
  65.  
  66. (welcome)
  67.  
  68. (set @default-dest
  69.   (askdir
  70.     (prompt #choose-dest)
  71.     (help @askdir-help)
  72.     (default @default-dest)
  73.   )
  74. )
  75.  
  76. (set @default-dest (tackon @default-dest "BackMan"))
  77.  
  78. ;**
  79. ;**  Copy binaries
  80. ;**
  81.  
  82. (complete 0)
  83.  
  84. (copyfiles
  85.   (prompt #inst-bin)
  86.   (source "BackMan")
  87.   (dest @default-dest)
  88. )
  89.  
  90. (complete 10)
  91.  
  92. (copyfiles
  93.   (prompt #inst-bin)
  94.   (source "BackManMUI")
  95.   (dest @default-dest)
  96.   (infos)
  97. )
  98.  
  99. (complete 20)
  100.  
  101. (if (exists "BackMan.Key") (
  102.   (message #welcome)
  103.   (copyfiles
  104.     (prompt #inst-key)
  105.     (source "BackMan.Key")
  106.     (dest @default-dest)
  107.   )
  108. ))
  109.  
  110. ;**
  111. ;**  Copy catalogs
  112. ;**
  113.  
  114. (complete 30)
  115.  
  116. (if (exists "LOCALE:" (noreq)) (
  117.   (if (> @user-level 0) (
  118.     (set #bitmask
  119.       (askoptions
  120.         (prompt #choose-catlang)
  121.         (help @askoptions-help)
  122.         (choices "Italiano")
  123.       )
  124.     )
  125.   )(
  126.     (set #bitmask -1)
  127.   ))
  128.  
  129.   (set n 0)
  130.   (while (set #language (select n "Italiano" "")) (
  131.     (if (IN #bitmask n) (
  132.       (copyfiles
  133.         (prompt #inst-cat)
  134.         (source (tackon "Locale/Catalogs" #language))
  135.         (dest (tackon (tackon @default-dest "Locale/Catalogs") #language))
  136.         (all)
  137.       )
  138.     ))
  139.     (set n (+ n 1))
  140.   ))
  141. ))
  142.  
  143. ;**
  144. ;**  Copy docs
  145. ;**
  146.  
  147. (complete 40)
  148.  
  149. (if (OR (< @user-level 2) (askbool (prompt #ask-doc) (help @askbool-help))) (
  150.   (if (> @user-level 0) (
  151.     (set #language
  152.       (select
  153.         (askchoice
  154.           (prompt #choose-doclang)
  155.           (help @askchoice-help)
  156.           (choices "English" "Italiano")
  157.           (default #langnum)
  158.         )
  159.         "English" "Italiano"
  160.       )
  161.     )
  162.   ))
  163.  
  164.   (complete 50)
  165.  
  166.   (copyfiles
  167.     (prompt #inst-doc)
  168.     (source "Docs")
  169.     (dest @default-dest)
  170.     (choices "RegistrationForm" "History")
  171.     (files)
  172.     (infos)
  173.   )
  174.  
  175.   (complete 60)
  176.  
  177.   (copyfiles
  178.     (prompt #inst-doc)
  179.     (source (tackon "Docs" #language))
  180.     (dest @default-dest)
  181.     (all)
  182.     (infos)
  183.   )
  184.  
  185.   (complete 70)
  186.  
  187.   (copyfiles
  188.     (prompt #inst-hlp)
  189.     (source (tackon "Help" #language))
  190.     (dest @default-dest)
  191.     (all)
  192.     (infos)
  193.   )
  194. ))
  195.  
  196. ;**
  197. ;**  Copy XPK libraries
  198. ;**
  199.  
  200. (complete 80)
  201.  
  202. (copylib
  203.   (prompt #inst-xpk "xpkmaster.library")
  204.   (help @copylib-help)
  205.   (source "Libs/xpkmaster.library")
  206.   (dest "LIBS:")
  207.   (optional nofail force)
  208.   (confirm)
  209. )
  210.  
  211. (complete 90)
  212.  
  213. (foreach "Libs/Compressors" "xpk????.library" (
  214.   (copylib
  215.     (prompt #inst-xpk @each-name)
  216.     (help @copylib-help)
  217.     (source (tackon "Libs/Compressors" @each-name))
  218.     (dest "LIBS:Compressors")
  219.     (optional nofail force)
  220.     (confirm)
  221.   )
  222. ))
  223.  
  224. ;**
  225. ;**  Installation complete!
  226. ;**
  227.  
  228. (complete 100)
  229.  
  230. (exit)
  231.  
  232. ;*** EOF ***
  233.